19.7.RPGの中で状況メッセージを送るAPI

     H            Y/                                    1
     FZZI070D CF  E                    WORKSTN
     F                                              KINFDS INFDSP
     I******************************************************
     I*     D E F I N E    D A T A  - S T R U C T U R E    *
     I******************************************************
     IINFDSP      DS
     I                                      369 369 PUSHED
     ICPFMGF      DS
     I I            'QCPFMSG'                 1  10 CPFMFL
     I I            '*LIBL'                  11  20 CPFMLB
     I*
     I           IDS
     I                                    B   1   40MSGLEN
     I                                    B   5   80TOPGCT
     I*
     IPBERR       DS
     I I            116                   B   1   40BYTPRV
     I I            0                     B   5   80BYTAVA
     I                                        9  15 ERRID
     I                                       16  16 ERR###
     I                                       17 116 ERRDTA
     I******************************************************
     I*     D E F I N E    C O N S T A N T                 *
     I******************************************************
     I              X'33'                 C         F3
     I              '実行開始! '        C         #STR
     I              '実行中... '        C         #ACTV
     I              '実行完了! '        C         #END
     C******************************************************
     C*             M A I N -  R O U T I N E               :
     C******************************************************
B001 C           F3        DOUEQPUSHED                     :
 001 C                     EXFMTHED01                      :OPTION ENTRY
B002 C           F3        IFNE PUSHED                     :
 002 C                     MOVE 'CPF9897' MSGID            :
 002 C                     MOVEL#STR      MSG              :
 002 C                     EXSR @STSMG                     :
 002 C                     EXSR @DLY                       :
 002 C*                                                    :
 002 C                     MOVE 'CPF9897' MSGID            :
 002 C                     MOVEL#ACTV     MSG              :
 002 C                     EXSR @STSMG                     :
 002 C                     EXSR @DLY                       :
 002 C*                                                    :
 002 C                     MOVE 'CPF9897' MSGID            :
 002 C                     MOVEL#END      MSG              :
 002 C                     EXSR @STSMG                     :
 002 C                     EXSR @DLY                       :
 002 C*メッセージを消す                                    :
 002 C                     MOVE 'CPF9897' MSGID            :
 002 C                     MOVE *BLANK    MSG              :
 002 C                     EXSR @STSMG                     :
 002 C*                                                    :
E002 C                     END                             :
E001 C                     END                             :
     C*                                                    :
     C                     MOVE *ON       *INLR            :
     C                     RETRN                           :
     C******************************************************
     C*             S U B   -  R O U T I N E               :
     C******************************************************
     C*----------------------------------------------------*
     C           @STSMG    BEGSR                           :
     C*----------------------------------------------------*
     C                     CALL 'QMHSNDPM'                 :
     C                     PARM           MSGID   7        :
     C                     PARM           CPFMGF           :
     C                     PARM           MSG    78        :
     C                     PARM 78        MSGLEN           :
     C                     PARM '*STATUS' MSGTYP 10        :
     C                     PARM '*EXT'    TOPGMQ 10        :
     C                     PARM           TOPGCT           :
     C                     PARM           KEYVAR  4        :
     C                     PARM           PBERR            :
     C*                                                    :
     C                     MOVE *BLANK    MSG              :
     C*                                                    :
     C                     ENDSR                           :
     C*----------------------------------------------------*
     C           @DLY      BEGSR                           :
     C*----------------------------------------------------*
     C*処理中のつもり
B001 C           1         DO   300000                     :
E001 C                     END                             :
     C*                                                    :
     C                     ENDSR                           :